Exporter un vidéo et des images en haute résolution avec PowerPoint

Il est possible d’exporter toutes les acétates PowerPoint sous formes d’images (à partir de Fichier > Sauvegarder sous, et choisir un format d’images) ou de vidéo (à partir de Fichier > Exporter > Créer un vidéo).   Toutefois, la résolution par défaut est HD (720 lignes) alors que je souhaite un vidéo en pleine résolution (Full HD, 1080) et des images à la plus haute résolution disponible.

Pour exporter les images avec une plus haute résolution, il existe un article de la base de connaissance Microsoft pour changer la résolution qui implique une modification aux clés de registre, mais qui ne s’applique pas à l’exportation vidéo.

Si vous avez des aptitudes à la programmation, voici comment exporter dans un format haute définition avec un module VBA.

1. À partir du document PowerPoint, accédez à l’éditeur VBA (Visual Basic for Applications) avec ALT+F11. Insérez un module et coller le code ci-dessous.  Modifier le code pour les chemins et noms voulus (les dossiers doivent exister pour le code s’exécute correctement).

 

Option Explicit

Sub ExportVideoFullHD()
  ' Original source: http://answers.microsoft.com/en-us/office/forum/office_2013_release-powerpoint/powerpoint-high-quality-video-export-1080p/cea47417-8b37-4aee-a57a-d589845a1b66

  ' Where should we put the video and what should
  ' we name it. NOTE: the folder must exist.
  If ActivePresentation.CreateVideoStatus <> ppMediaTaskStatusInProgress Then
    ActivePresentation.CreateVideo FileName:=Environ("USERPROFILE") & "\Desktop\test.wmv", _
      UseTimingsAndNarrations:=True, _
      VertResolution:=1080, _
      FramesPerSecond:=25, _
      Quality:=100
  Else
    MsgBox "There is another conversion to video in progress"
  End If
End Sub

Sub ExportSlidesHighRes()
  ' Original source: http://www.pptfaq.com/FAQ00052_Improve_PowerPoint-s_GIF-_BMP-_PNG-_JPG_export_resolution.htm
  ' Official method: https://support.microsoft.com/en-us/kb/827745

  ' Where should we put the images and what should
  ' we name them. NOTE: the folder must exist.
  Dim OutputFolder As String
  OutputFolder = Environ("USERPROFILE") & "\Desktop\Slides\"
  Const ImageBaseName As String = "Slide_"

  ' Export dimensions in pixels:
  ' Width/Height should be proportional to
  ' PPT's slide width/height
  ' For 16:9 (wide screen format), use 4000x2250
  ' For other formats, refer to https://support.microsoft.com/en-us/kb/827745
  Const ImageWidth As Long = 4000
  Const ImageHeight As Long = 2250

  ' Export as what format
  ' Can be PNG, JPG, BMP, ...
  Const ImageType As String = "PNG"

  Dim slide As slide

  For Each slide In ActivePresentation.Slides
    slide.Export OutputFolder & ImageBaseName & Format(slide.SlideIndex, "0000") & "." & ImageType, _
      ImageType, ImageWidth, ImageHeight
  Next
End Sub


2. Sauvegarder le document (vous devrez probablement le convertir à un format « pptm » compatible avec les macros).

3. Lancer la commande : Affichage > Macros > Exécuter. Dans la boîte de dialogue, exécuter la macro voulue… Cela peut prendre un certain temps!

Clause de non responsabilité. Les exemples de scripts sur ce site ne sont pas supportés par aucun programme ou service de soutien. Les exemples de scripts sont fournis tels quels, sans garantie d’aucune sorte.

Advertisements

Laisser un commentaire

Entrez vos coordonnées ci-dessous ou cliquez sur une icône pour vous connecter:

Logo WordPress.com

Vous commentez à l'aide de votre compte WordPress.com. Déconnexion / Changer )

Image Twitter

Vous commentez à l'aide de votre compte Twitter. Déconnexion / Changer )

Photo Facebook

Vous commentez à l'aide de votre compte Facebook. Déconnexion / Changer )

Photo Google+

Vous commentez à l'aide de votre compte Google+. Déconnexion / Changer )

Connexion à %s